Il est obligatoire d'être présent au début de l'épreuve .

Il est formellement interdit de quitter la salle avant la fin de l'épreuve .  

La durée de l'épreuve est de 2 heures.

Aucun document n'est autorisé, la calculatrice n'est pas autorisée.

Sur l'ordinateur mis à service, seul le logiciel " maple " est utilisable : internet et intranet sont mis hors service, les moyens de communication sont coupés (mail, telnet, ...), la sauvegarde ainsi que l'accès aux documents personnel sont également exclus.

Le téléphone portable est évidemment interdit aussi.

Le compte-rendu est à rendre uniquement sur copie et manuscrit  : pas de sortie imprimante, pas d'enregistrement de fichier.

>    restart:

Questions de cours

1) Donner des coefficients a , b , c et d  réels tels que cos(7*x) = a*cos(x)^7+b*cos(x)^5+c*cos(x)^3+d*cos(x) .

2 points

2) Donner le polynôme p tel que x^9-x^6+x^3-1 = (x^2+1)*p(x) .

2 points

3) Trouver u  et v  deux entiers relatifs tels que 9625*u+840*v = 1 .

2 points

>    expand(cos(7*x));

64*cos(x)^7-112*cos(x)^5+56*cos(x)^3-7*cos(x)

>    simplify((x^9-x^6+x^3-1)/(x^2+1));

x^7-x^5-x^4+x^3+x^2-1

>    igcdex(9625,841,'s','t');

1

>    s; t;
-416*9625+4761*841;

-416

4761

1

>    restart:

Exercice 1 . Géométrie affine.

Soit ( O , i , j ) un repère orthonormé direct.

Soient A le point de coordonnées (0,0), E le point de coordonnées (1,0), ABCD un carré direct et BEFG un carré direct également.

Quel est le lieu géométrique du milieu I du segment [DF] lorsque le point B varie dans le plan ?

[Maple Metafile]

Démarche proposée  : on considère que le point B a pour coordonnées (x,y),

a) donner les coordonnées du point D,

b) donner les coordonnées du point F,

c) donner les coordonnées du point I et conclure.

3 points

>    a:=[0,0];e:=[1,0];b:=[x,y];
ad:=[-y,x];d:=a+ad;
ef:=[y,1-x];f:=e+ef;
i:=(d+f)/2;

a := [0, 0]

e := [1, 0]

b := [x, y]

ad := [-y, x]

d := [-y, x]

ef := [y, 1-x]

f := [y+1, 1-x]

i := [1/2, 1/2]

>    restart:

Exercice 2 . Fonctions de chiffres.

Chercher un nombre naturel de la forme abbcca  (en base 10 ,  a  est chiffre des centaines de milliers et des unités supposé non nul, b est chiffre des dizaines de millers et des miliers, c  est chiffre des dizaines et des centaines) qui soit un carré parfait (i.e. le carré d'un nombre naturel).

Combien existe-t-il de nombres de la fome abbcca  qui soient des carrés parfaits ?

3 points

>    L:=NULL:
for a from 1 to 9 do
for b from 0 to 9 do
for c from 0 to 9 do
N:=100001*a+11000*b+110*c; if simplify(sqrt(N))=floor(sqrt(N)) then L:=L,N fi:
od:
od:
od:
L:=[L];nops(L);
SQRT:=NULL:
for i from 1 to nops(L) do SQRT:=SQRT,sqrt(L[i]) od:
SQRT:=[SQRT];

L := [511225]

1

SQRT := [715]

>    restart:

Exercice 3 . Algèbre linéaire.

a  est un paramètre réel. Soit A = matrix([[1, 10, 100], [10, 100, a], [100, a, 10]]) , soit X = matrix([[x], [y], [z]])  et soit B = matrix([[111], [111], [111]]) .

Pour quelle(s) valeur(s) de a , la matrice A  est-elle inversible ?

      Lorsque A  est inversible, donner la matrice inverse de A .

1 point

      Lorsque A  n'est pas inversible, selon la valeur de a , donner l'image et le noyau de A .

1 point

Soit le système d'équations AX=B .

      Lorsque A  est inversible, X  est définie de façon unique par X = A^(-1)*B . Donner la matrice X .

1 point

      Lorsque A  n'est pas inversible, selon la valeur de a , donner l'ensemble des matrices X  répondant à la question.

1 point

>    with(linalg): 

Warning, the protected names norm and trace have been redefined and unprotected

>    A:= matrix([[1, 10, 100], [10, 100, a], [100, a, 10]]);
X:= matrix([[x], [y], [z]]);
B:= matrix([[111], [111], [111]]);

A := matrix([[1, 10, 100], [10, 100, a], [100, a, 10]])

X := matrix([[x], [y], [z]])

B := matrix([[111], [111], [111]])

>    Ainv:=factor(inverse(A));

Ainv := matrix([[(-1000+a^2)/(a^2-2000*a+1000000), -100*(a-1)/(a^2-2000*a+1000000), -10/(a-1000)], [-100*(a-1)/(a^2-2000*a+1000000), 9990/(a^2-2000*a+1000000), 1/(a-1000)], [-10/(a-1000), 1/(a-1000), 0...

>    solve(a^2-2000*a+1000000=0,a);solve(a-1000=0,a);
#Lorsque a=1000, la matrice A n'est pas inversible.

1000, 1000

1000

>    simplify(multiply(Ainv,B));

matrix([[111*(a^2-110*a+9100)/(a-1000)^2], [-999*(11*a-1010)/(a-1000)^2], [-999/(a-1000)]])

>    a:=1000:A:= matrix([[1, 10, 100], [10, 100, a], [100, a, 10]]);

A := matrix([[1, 10, 100], [10, 100, 1000], [100, 1000, 10]])

>    colspace(A);#image de A
nullspace(A);#noyau de A

{vector([1, 10, 0]), vector([0, 0, 1])}

{vector([-10, 1, 0])}

>    solve({x+10*y+100*z=111,10*x+100*y+1000*z=111,100*x+1000*y+10*z=111},{x,y,z});
#pas de solution !

>    restart:

Exercice 4 . Minimisation d'une aire.

Soit (O, i , j ) un repère orthonormé.

On considère l'ensemble Gamma  des points M ( x, sqrt(1-x^2) ) pour x  variant entre 0  et 1 .

1) Soit T[M]  la tangente en M  à l'ensemble Gamma . Donner l'équation de la tangente T[M] .

1 point

2) La tangente T[M]  coupe l'axe ( O i ) en un point A  et l'axe ( O j ) en un point B . Donner les coordonnées des points A  et B .

1 point

3) Donner l'aire du triangle OAB  en fonction de x .

1 point

4) Donner la valeur (ou les valeurs) de x  pour que le triangle OAB  ait une aire extrémale.

5) Donner la valeur (ou les valeurs) de x  pour que le triangle OAB  ait une aire minimale.    

1 point

>    f:=x->sqrt(1-x^2);
M:=[x,f(x)];#coordonnées de M
T:=X->diff(f(x),x)*(X-x)+f(x);#la fonction T donne l'équation de la tangente à la courbe en M
solve(T(X)=0,X);#abscisse du point A
A:=[1/x,0];
T(0);#ordonnée du point B
B:=[0,1/(1-x^2)^(1/2)*x^2+(1-x^2)^(1/2)];
Aire:=x->simplify(1/2*(1/(1-x^2)^(1/2)*x^2+(1-x^2)^(1/2))*(1/x));#la fonction Aire donne l'aire du triangle OAB en fonction de x
diff(Aire(x),x);
solve(diff(Aire(x),x)=0,x);#les points critiques sont en 0 (bord gauche), en 1 (bord droit), et en 1/2*2^(1/2) ;
limit(Aire(x),x=0,right);#en 0, la limite est +infinity ;
limit(Aire(x),x=1,left);#en 1, la valeur est +infinity ;
Aire(1/2*2^(1/2));#en 1/2*2^(1/2), la valeur de l'Aire est 1 et le tableau de variations nous permet de conclure qu'il s'agit d'un minimum.

f := proc (x) options operator, arrow; sqrt(1-x^2) end proc

M := [x, (1-x^2)^(1/2)]

T := proc (X) options operator, arrow; diff(f(x),x)*(X-x)+f(x) end proc

1/x

A := [1/x, 0]

1/(1-x^2)^(1/2)*x^2+(1-x^2)^(1/2)

B := [0, 1/(1-x^2)^(1/2)*x^2+(1-x^2)^(1/2)]

Aire := proc (x) options operator, arrow; simplify(1/2*(1/(1-x^2)^(1/2)*x^2+(1-x^2)^(1/2))/x) end proc

1/(2*(1-x^2)^(3/2))-1/(2*(1-x^2)^(1/2)*x^2)

1/2*2^(1/2), -1/2*2^(1/2)

infinity

infinity

1

>    Fin (Philippe RYCKELYNCK & Denis VEKEMANS) 

Error, missing operator or `;`